※本情報は私のGeForceを利用したFF14環境における異常発生解決について記載しておりますが、スクウェア・エニックス様ならびにNvidiaグラフィックカード提供各社様未保証です。内容の実践は自己責任でお願い致します。PS4でプレイしていたFF14をPCでプレイすべく、グラボをGeForce GTRX970に変更しましたが、
最高品質にするとOS再起動、グラフィックドライバリセットが発生していました。
・グラフィックドライバの再起動の警告（OSにて対処ができたパターン）
・画面が単色になり、数秒フリーズのうちPC再起動（OSで対処できなかったパターン）
・画面が単色になり、フリーズのまま
・FF14ベンチは正常フォーラムやネット上の記事などを参考に調査をした結果、2条件が重なると発生すると判明しました。(1)人で混雑した場所（リムサ・ロミンサ東国際商通り）など、所謂「
重い」場所
(2)現在のGeForceに標準搭載されている
GPU Boost機能が働き、
GPU動作周波数が自動的にオーバークロックする私の環境(GTX970)では1300MHz近くまでオーバークロックされており、
仕様からすると耐えられる（
現にベンチでは耐えている）のですが、結果的に定格周波数以上でリムサの重みの中にいるとPCが落ちる環境だと判明しました。
残念ながらGPU Boost機能はユーザー操作で無効にできる仕組みが用意されていない為、
「
Nvidia Inspector」なる寄付ウェアを利用し、GPU周波数を定格のままで
稼働させることにしました。現在のところ2時間以上リムサに棒立ちですが現象発生していません。
環境によっては電源ユニットのPCI-E電源品質不良などがあると思いますが、
現状定格で動作させられることがわかったのでこれでプレイできそうです。
※試そうとされる方へ：MSI社等、一部メーカーではオーバークロック設定変更の為のソフトウェアを公開しています。
メーカー提供のソフトウェアがある場合はそちらを優先的に試されることをオススメします。***********************************************************************
Nvidia Inspectorの情報の調査がてら、バッチファイルを作成しました。
本来の周波数固定機能/固定解除に加え、周波数固定に続いてFF14ランチャー起動ができます。
（機能分けた方が使いやすいですけどね）使用する為にはNvidia Inspector、P-State番号、GPU周波数、メモリ周波数、FF14ランチャーのフルパスが必要です。
実際に効果が現れているかはNvidia Inspectorで確認してください。
(1)Nvidia InspectorでP-Stateの0の次の値(P2,P5など)を確認しておきます。
(2)隠しの開いた内容をすべてコピーし、メモ帳に保存した後、拡張子をbatに変更するとバッチファイルになります。
(3)個別設定を変更し、Nvidia Inspectorと同じフォルダに置いて使用します。
(4)各GeForceによって値は違いますので個別設定は注意してください。
(5)値が反映されない場合、Nvidia InspectorのUnlock Maxが必要かもしれません。
***********************************************************************
cd %~dp0
setlocal
echo □■□■□■□■□■□■□■□■□■□■□■□■□■□■
echo □■ ＊使用にあたって＊ □■
echo □■はじめに必ず、このファイルをメモ帳で開き □■
echo □■個別設定の値を最適な情報に変更してください。 □■
echo □■本ファイルは複数枚カード搭載は非対応です。 □■
echo □■必要な値（P-State/周波数）は □■
echo □■Nvidia Inspectorで確認してください。 □■
echo □■また、本ファイルの利用は自己責任でお願いします。□■
echo □■□■□■□■□■□■□■□■□■□■□■□■□■□■
pause.
CLS
rem □■□■□■□■個別設定 適宜変更□■□■□■□■
rem GPU番号。複数枚環境で意味の分かる人以外変更不要。
set GPUNUM=0
rem 動作モード定義番号。Nvidia InspectorのShow OverClockingで確認。
rem P0の次の番号を使う。GTX970=2
set PSTATE=2
rem GPU周波数。GPU Boostに任せているとBoost値以上にGPU Clockがあがる。
rem 定格より上げると間欠で落ちはじめ、周波数上昇に伴い落ちる周期が短くなっていく。
rem GTX970=1076
set GPUCLOCK=1076
rem メモリ周波数。動作モードにより既に値が決まっているので基本的には指定しない。
rem GTX970=3004
set MEMCLOCK=3004
rem FF14ランチャーの場所。フルパス指定。
set FF14="D:\Program Files (x86)\SquareEnix\FINAL FANTASY XIV - A Realm Reborn\boot\ffxivboot.exe"
rem □■□■□■□■個別設定 ここまで□■□■□■□■
:MENU
CLS
echo □■□■Nvidia Inspector用設定バッチファイル□■□■
echo (1)│P-State:%PSTATE%に固定,GPU-Clock:%GPUCLOCK%MHz固定
echo ─┼───────────────────────
echo (2)│(1)+MEM-Clock:%MEMCLOCK%MHz固定
echo ─┼───────────────────────
echo (3)│(1)→FF14起動
echo ─┼───────────────────────
echo (4)│(2)→FF14起動
echo ─┼───────────────────────
echo (5)│(欠番）
echo ─┼───────────────────────
echo (6)│(欠番）
echo ─┼───────────────────────
echo (7)│P-State固定の解除
echo ─┼───────────────────────
echo (8)│ディスプレイドライバのリセット
echo ─┼───────────────────────
echo (9)│終了
choice /c:123456789
if errorlevel 9 goto EOF
if errorlevel 8 goto RESETDRIVER
if errorlevel 7 goto PSTATERESET
if errorlevel 6 goto EOF
if errorlevel 5 goto EOF
if errorlevel 4 goto 2ANDFF14
if errorlevel 3 goto 1ANDFF14
if errorlevel 2 goto BOTH
if errorlevel 1 goto GPUONLY
:GPUONLY
nvidiaInspector.exe -forcepstate:%GPUNUM%,%PSTATE% -setGpuClock:%GPUNUM%,%PSTATE%,%GPUCLOCK%
CLS
echo (1)実行完了。メニューに戻ります。
pause.
goto MENU
:BOTH
nvidiaInspector.exe -forcepstate:%GPUNUM%,%PSTATE% -setGpuClock:%GPUNUM%,%PSTATE%,%GPUCLOCK% -setMemoryClock:%GPUNUM%,%PSTATE%,%MEMCLOCK%
CLS
echo (2)実行完了。メニューに戻ります。
pause.
goto MENU
:1ANDFF14
nvidiaInspector.exe -forcepstate:%GPUNUM%,%PSTATE% -setGpuClock:%GPUNUM%,%PSTATE%,%GPUCLOCK%
CLS
%FF14%
goto MENU
:2ANDFF14
nvidiaInspector.exe -forcepstate:%GPUNUM%,%PSTATE% -setGpuClock:%GPUNUM%,%PSTATE%,%GPUCLOCK% -setMemoryClock:%GPUNUM%,%PSTATE%,%MEMCLOCK%
CLS
%FF14%
goto MENU
:PSTATERESET
nvidiaInspector.exe -forcepstate:%GPUNUM%,16
CLS
echo P-State固定解除完了。メニューに戻ります。
echo Clockが戻らない場合はドライバリセットを実行するかPCを再起動してください
pause.
goto MENU
:RESETDRIVER
echo ディスプレイドライバリセットの為、画面が一時無表示になります。
pause.
nvidiainspector.exe -restartDisplayDriver
goto MENU